* Modele no. 8 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu
*
*  Ce modele introduit les deux technologies dans le contexte regional.

SET i /sorgho, mil , niebe, coton, mais/ ;
SET r/cereal,coton,bamako/;
ALIAS(r,q);
PARAMETERS A(i,r), B(i,r);
POSITIVE VARIABLES D(i,r), TC(i,r),TR(i,r);  
VARIABLE BES ;
EQUATION objectif ;
objectif .. BES =E= sum(i,
       sum(r,A(i,r)*D(i,r)*D(i,r)/2 + B(i,r)*D(i,r) - TC(i,r) - TR(i,r))) ; 

* Pour la contrainte des terres il nous faut introduire l'ensemble
* des deux technologies - traditionelle et ameliore 

SET j /trad, ameliore/;
POSITIVE VARIABLE X(i,j,r);
EQUATION terres(r);
PARAMETER S(r);
terres(r) .. SUM( i, sum(j, X(i,j,r)) ) =L= S(r);

EQUATION equilibre(i,r);
POSITIVE VARIABLE O(i,r) ;
VARIABLE T(i,q,r);
equilibre(i,r) .. D(i,r) =L= O(i,r) + SUM(q, T(i,q,r)) ; 

EQUATIONS calcoffre(i,r), calccouts(i,r) ;
PARAMETER Y(i,j,r), c(i,j) ;
calcoffre(i,r) .. SUM(j, -Y(i,j,r)*X(i,j,r) +O(i,r)) =E= 0;  
calccouts(i,r) ..  SUM(j,-c(i,j)*X(i,j,r) +TC(i,r)) =E= 0;  

EQUATION calctransp(i,r);
PARAMETER h(i,q,r);
POSITIVE  VARIABLE TR(i,r);
calctransp(i,r) .. -SUM(q, h(i,q,r)*T(i,q,r)) + TR(i,r)=E= 0;

EQUATION equiltrans(i,q,r);
equiltrans(i,q,r) .. T(i,q,r) + T(i,r,q) =E= 0;

PARAMETER Dequil(i,r), Pequil(i,r);
PARAMETER subsist;
subsist = 180;
SET type /rurale, urbane/;
PARAMETER popcereal(type), popcoton(type), popbamako;
popcereal('rurale') = 4192000;
popcereal('urbane') = 999000;
popcoton('rurale') = 2508000;
popcoton('urbane') = 551000;
popbamako = 941000;

Dequil('sorgho','cereal') = .45*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('sorgho','coton') = .45*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('sorgho','bamako') = .25*subsist*popbamako;

Dequil('mil   ','cereal') = .45*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('mil   ','coton') = .45*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('mil   ','bamako') = .25*subsist*popbamako;

Dequil('niebe','cereal') = 50*(popcereal('rurale')+popcereal('urbane'));
Dequil('niebe','coton') = 50*(popcoton('rurale')+popcoton('urbane'));
Dequil('niebe','bamako') = 50*popbamako;

Dequil('mais','cereal') = .1*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('mais','coton') = .1*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('mais','bamako') = .1*subsist*popbamako;

Dequil('coton','cereal') = 1;
Dequil('coton','bamako') = 1;
Dequil('coton','coton') = 452046000;

Pequil('sorgho',r) = 99;
Pequil('mil',r) = 97;
Pequil('niebe',r) = 171;
Pequil('coton',r) = 155;
Pequil('mais',r) = 83;

* Dans ce cas on veut permettre differentes elasticites de la demande,
* car l'elasticite pour le coton dans la zone cotoniere est tres grande.

PARAMETER epsilon(i,r) ;
epsilon('sorgho',r) = -.5;
epsilon('mil   ',r) = -.5;
epsilon('niebe',r) = -.5;
epsilon('mais',r) = -.5;
epsilon('coton','cereal') = -.1;
epsilon('coton','bamako') = -.1;
epsilon('coton','coton') = -10000000;

A(i,r) = Pequil(i,r)/(Dequil(i,r)*epsilon(i,r)) ;
B(i,r) = Pequil(i,r)*(1 - 1/epsilon(i,r)) ;

Y('sorgho','trad','cereal') = 570;  
Y('sorgho','ameliore','cereal') = 1430;  
Y('sorgho','trad','coton') = 1100;  
Y('sorgho','ameliore','coton') = 1600;  

Y('mil','trad','cereal') = 570;  
Y('mil','ameliore','cereal') = 1100;  
Y('mil','trad','coton') = 900;  
Y('mil','ameliore','coton') = 1200;  

Y('niebe','trad','cereal') = 1300;  
Y('niebe','ameliore','cereal') = 1430;  

Y('coton','trad','coton') = 1200;  
Y('coton','ameliore','coton') = 2436;  

Y('mais','trad','coton') = 2500;  
Y('mais','ameliore','coton') = 3000;  
 
S('cereal') = 901906 ;
S('coton') = 1189789 ;

TABLE C(i,j)
            trad    ameliore
sorgho      1500     22250
mil         1500     22250 
niebe       1500     23000
coton       32000    52200
mais        51500    55500 ;
 
H(i,q,r) = 0;

MODEL modele8 /objectif, terres, equilibre, 
                calcoffre, calccouts, calctransp, equiltrans/ ;
SOLVE modele8 maximizing BES using NLP;