* Modele no. 5 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu

SET i /sorgho, mil, niebe/ ; 
SET k /seche, moyenne, bonne/ ;
EQUATION objectif;
POSITIVE VARIABLES O(i,k), TC(i) ;
VARIABLES eprofit, profit(k);

TABLE P(i,k)
             seche  moyenne   bonne
sorgho         117      97      72 
mil            123      99      79  
niebe          191      171     161 ;

PARAMETER prob(k);
objectif ..  eprofit =E= SUM(k,prob(k)*profit(k) );    

EQUATION natuprofit(k) ;
natuprofit(k) .. profit(k) =E= SUM(i,P(i,k)*O(i,k) - TC(i));

SET j /trad, ameliore/;
POSITIVE VARIABLE X(i,j);
EQUATION terres;
PARAMETER S;
terres .. SUM( i,  SUM(j, X(i,j))   ) =L= S;

EQUATIONS calcoffre(i,k), calccouts(i) ;

* Maintenant nous voulons declarer et afficher les donnes pour
* un parametre a trois dimensions.  Il faut toujours aller de
* gauche a droite, commenceant dans ce cas par le produit (i),
* avec un point (.) pour le separer de la technologies (j).
* Ainsi la combinaison (i.j) forment les rangees et l'etat-de-nature 
* (k) forme les colonnes.

TABLE Y(i,j,k)
                 seche  moyenne   bonne
sorgho.trad      470      570      620
sorgho.ameliore  870     1430      1460
mil     .trad      450      570      670 
mil   .ameliore  870      1100     1200
niebe.trad       830     1300      1420
niebe.ameliore   1090    1430      1521 ;

TABLE C(i,j)
            trad    ameliore
sorgho      1500     22250
mil         1500     22250 
niebe       1500     23000 ;

calcoffre(i,k) ..  -SUM(j, Y(i,j,k)*X(i,j)) + O(i,k) =E= 0;  
calccouts(i) ..  -SUM(j, c(i,j)*X(i,j)) +TC(i) =E= 0;  

PARAMETER DMO(i,j), OMO;
EQUATION labor;
labor .. SUM(i, SUM(j,DMO(i,j)*X(i,j))) =L= OMO; 

EQUATION liquiditee; 
PARAMETER argent;
liquiditee .. SUM(i, TC(i)) =L= argent ;


S = 16;
argent = 200000;
DMO('sorgho','trad') = 208;
DMO('sorgho','ameliore') = 227;
DMO('mil   ','trad') = 208;
DMO('mil   ','ameliore') = 227;
DMO('niebe','trad') = 379;
DMO('niebe','ameliore') = 440;
OMO = 9547 ;
prob('seche') = .3 ;
prob('moyenne') = .45 ;  
prob('bonne')=.25 ;

MODEL modele5 /objectif, natuprofit, terres,
                  calcoffre, calccouts, labor, liquiditee/ ;
SOLVE modele5 maximizing eprofit using LP;