* Modele no. 4 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu

* Pour ce modele nous avons besoin d'un nouvel ensemble pour
* les differentes conditions agro-climatiques (etats de la nature).

SET i /sorgho,  mil, niebe/ ; 
SET k /seche, moyenne, bonne/ ;

* Dans l'objectif nous avons le profit dans chaque etat-de-nature
* multiplie par sa probabilite, ce qui nous donne le profit espere (eprofit), 
* ce qui serait le profit moyen sur plusieurs annees. 

EQUATION objectif;
VARIABLES eprofit, profit(k);

* Maintenant on veut declarer les prix dans chaque etat-de-nature,
* et pour pouvoir les entrer sous forme de tableau il faut afficher
* les donnes juste apres la declaration du parametre avec 
* le mot-clef TABLE.
* Noter bien que le premier indice apres la parenthese doit representer 
* les rangees et le deuxieme indice les colonnes, et qu'il faut
* assurer que tout les chiffres commencent apres le debut du nom de 
* la colonne.  
* N'oubliez pas le point-virgule.

TABLE P(i,k)
             seche  moyenne   bonne
sorgho        117      97       72 
mil           123      99       79  
niebe         191      171     161 ; 

PARAMETER prob(k);
objectif ..  eprofit =E= SUM(k,prob(k)*profit(k) );    

* Pour calculer le profit dans chaque etat-de-nature il nous faut
* une nouvelle equation :

EQUATION NATUPROFIT(k) ;
POSITIVE VARIABLE X(i);
PARAMETER c(i);

TABLE Y(i,k)
                 seche  moyenne   bonne
sorgho           470      570      620
mil              450      570      670
niebe            830      1300     1420 ;

NATUPROFIT(k) .. profit(k) =E= SUM(i,P(i,k)*Y(i,k)*X(i) - c(i)*X(i));

EQUATION terres;
PARAMETER S;
terres .. SUM(i, X(i)) =L= S;

PARAMETER DMO(i), OMO;
EQUATION labor;
labor .. SUM(i, DMO(i)*X(i)) =L= OMO; 

EQUATION liquiditee; 
PARAMETER argent;
liquiditee .. SUM(i, c(i)*X(i)) =L= argent ;

* Ensuite on entre les donnes comme les autres modeles
S = 16;
c('sorgho') = 1500;  
c('mil') = 1500;  
c('niebe') = 1500;
DMO('sorgho') = 208;
DMO('mil') = 208;
DMO('niebe') = 379;
OMO = 9547 ;
argent = 200000;

* mais le nouvel element est la probabilite de
* chaque condition agro-climatique.  Evidemment 
* le total des probabilities doit etre un.

prob('seche') = .3 ;
prob('moyenne') = .45;  
prob('bonne')=.25;

* Finalement on peut creer le modele et lancer sa solution.
* Noter que le modele contient le nouvel equation pour calculer le
* profit sous chaque etat de nature, et que l'objectif est de
* maximizer le eprofit au lieu du profit.

MODEL modele4 /objectif, natuprofit, terres, labor, liquiditee / ;
SOLVE modele4 maximizing eprofit using LP;