* Modele no. 3 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu

* Ce modele commence comme le modele no. 2:

SET  i /sorgho, mil, niebe/ ; 
EQUATION objectif;
POSITIVE VARIABLES O(i), TC(i) ;
VARIABLES profit;
PARAMETER P(i) ;
objectif ..  profit =E= SUM(i, P(i)*O(i) - TC(i));

SET j /trad, ameliore/;
POSITIVE VARIABLE X(i,j);
EQUATION terres;
PARAMETER S;
terres .. SUM( i,  SUM(j, X(i,j))   ) =L= S;

EQUATIONS calcoffre(i), calccouts(i) ;
PARAMETER Y(i,j) ;
PARAMETER c(i,j);
calcoffre(i) ..  -SUM(j, Y(i,j)*X(i,j)) +O(i) =E= 0;  
calccouts(i) ..  -SUM(j, c(i,j)*X(i,j)) +TC(i) =E= 0;  

* Les elements nouveaux sont les contraintes qui insistent que
* les demandes pour la main d'oeuvre (DMO(i,j)) 
* ne depassent pas l'offre de la main d'oeuvre (OMO), et que
* le total des couts de production (TC(i))
* ne depassent pas la liquiditee disponible (argent).

PARAMETER DMO(i,j), OMO;
EQUATION labor;
labor .. SUM(i, SUM(j,DMO(i,j)*X(i,j))) =L= OMO; 
EQUATION liquiditee; 
PARAMETER argent;
liquiditee .. SUM(i, TC(i)) =L= argent ;

* On peut maintenant entrer les donnes, commenceant avec
* ceux qui sont les memes que pour le modele precedent:

S = 16;
Y('sorgho','trad') = 570;  
Y('sorgho','ameliore') = 1430;  
Y('mil','trad') = 570;  
Y('mil','ameliore') = 1100;  
Y('niebe','trad') = 1300;  
Y('niebe','ameliore') = 1430;  
c('sorgho','trad') = 1500;  
c('sorgho','ameliore') = 22250;  
c('mil','trad') = 1500;  
c('mil','ameliore') = 22250;  
c('niebe','trad') = 1500;  
c('niebe','ameliore') = 23000;  
P('sorgho') = 99;
P('mil') = 97;
P('niebe') = 171;

* L'argent liquide disponible pour payer les couts (en FCFA)

argent = 200000;

* La demande pour la main d'oeuvre en chaque activite (h/ha)

DMO('sorgho','trad') = 208;
DMO('sorgho','ameliore') = 227;
DMO('mil','trad') = 208;
DMO('mil','ameliore') = 227;
DMO('niebe','trad') = 379;
DMO('niebe','ameliore') = 440;

* L'offre de la main d'oeuvre supposant un complement de
* 4 hommes, 3 femmes et 4 enfants (en heures)

OMO = 9547 ;

* Finalement notez que le modele contient les deux equations
* nouvelles pour la main d'oeuvre et la liquiditee.

MODEL modele3 /objectif, terres ,calcoffre, calccouts, 
                labor, liquiditee/ ;
SOLVE modele3 maximizing profit using LP;