* Modele no. 2 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu

* Pour simplifier la presentation on ne mettra que les commentaires
* necessaires pour clarifier les elements que l'on ajoute au modele 
* precedent.
* L'objectif de ce modele est le meme que celui du modele 1, 
* mais pour simplifier la formule on le calcule avec deux variables
* intermediaires:
*    O(i) est l'offre de chaque produit
*    TC(i) est le total des couts de production pour chaque produit

SET i /sorgho,  mil, niebe/ ; 
EQUATION objectif;
POSITIVE VARIABLES O(i), TC(i) ;
VARIABLES profit;
PARAMETER P(i) ;
objectif ..  profit =E= SUM(i, P(i)*O(i) - TC(i));

* Maintenant pour la contrainte des terres il nous faut un
* ensemble additional pour representer les deux 
* technologies,  traditionelle et ameliore.  La repartition 
* des terres se fait en deux dimensions, par produit et par 
* technologie, et le variable X est donc defini sur deux indices.

SET j /trad, ameliore/;
POSITIVE VARIABLE X(i,j);
EQUATION terres;
PARAMETER S;
terres .. SUM( i,  SUM(j, X(i,j))   ) =L= S;

* Il nous reste a calculer les variables intermediaires, faisant
* la sommation sur toutes les technologies pour calculer
* l'offre totale (O(i)) et le total des couts (TC(i)).
* Notez la convention d'ecrire les equations avec tous
* les variables a gauche et un zero a droite.

EQUATIONS calcoffre(i), calccouts(i) ;
PARAMETER Y(i,j) ;
PARAMETER c(i,j);
calcoffre(i) ..  -SUM(j, Y(i,j)*X(i,j)) +O(i) =E= 0;  
calccouts(i) ..  -SUM(j, c(i,j)*X(i,j)) +TC(i) =E= 0;  

* Maintenant on passe a l'entree des donnes, precisant 
* le produit et la technologie.  Rappelons les unites:
* S est en hectares
* Y est en kg/ha
* c  est en FCFA/ha
* P est en FCFA/kg

S = 16;
Y('sorgho','trad') = 570;  
Y('sorgho','ameliore') = 1430;  
Y('mil','trad') = 570;  
Y('mil','ameliore') = 1300;  
Y('niebe','trad') = 1300;  
Y('niebe','ameliore') = 1521;  
c('sorgho','trad') = 1500;  
c('sorgho','ameliore') = 22250;  
c('mil','trad') = 1500;  
c('mil','ameliore') = 22250;  
c('niebe','trad') = 1500;  
c('niebe','ameliore') = 23000;  
P('sorgho') = 99;
P('mil') = 97;
P('niebe') = 171;

* Finalement on peut creer le modele et lancer sa solution.
* Noter bien que ce modele comprend quatre equations, dont deux
* ne servent qu'a calculer des variables intermediaires.

MODEL modele2 /objectif, terres, calcoffre, calccouts/ ;
SOLVE modele2 maximizing profit using LP;