* Modele no.10 du manuel sur 
* ADOPTION ET L"IMPACT DES NOUVELLES TECHNOLOGIES
* William Masters et Jeffrey Vitale (Purdue Univ.), nov. 1998
* 1145 Krannert Bldg., West Lafayette IN 47907
* ph. 1 765 494 4235, fax 1 765 494 9176
* masters@agecon.purdue.edu; vitale@agecon.purdue.edu

* Ce modele impose des limites sur l'utilisation des engrais
* au niveau national, et sur l'utilisation de la main d'oeuvre
* dans chaque region, dans le contexte de l'adoption des
* nouvelles technologies.


SET i /sorgho, mil , niebe, coton, mais/ ;
SET r /cereal, coton, bamako/;
SET k /seche, moyenne, bonne/ ;
ALIAS (r,q);
PARAMETERS A(i,r), B(i,r);
POSITIVE VARIABLES D(i,r,k), TC(i,r), TR(i,r,k);  
VARIABLE EBES, SW(k) ;
EQUATION objectif ;
PARAMETER prob(k);
objectif .. EBES =E= sum(k,prob(k)*  
   sum((i,r),A(i,r)*D(i,r,k)*D(i,r,k)/2 + B(i,r)*D(i,r,k) -
   TC(i,r) - TR(i,r,k) )) ;

SET j /trad, ameliore/;
POSITIVE VARIABLE X(i,j,r);
EQUATION terres(r);
PARAMETER S(r);
terres(r) .. SUM(i, SUM(j, X(i,j,r)) ) =L= S(r);

EQUATION equilibre(i,r,k) ;
POSITIVE VARIABLE O(i,r,k) ;
VARIABLE T(i,q,r,k) ;
equilibre(i,r,k) .. D(i,r,k) =L= O(i,r,k) + SUM(q, T(i,q,r,k)) ; 

EQUATIONS calcoffre(i,r,k), calccouts(i,r) ;
TABLE Y(i,j,r,k)
                        seche  moyenne   bonne
sorgho.trad.cereal      470     570       620
sorgho.ameliore.cereal  870     1430      1460
sorgho.trad.coton       570     698       830 
sorgho.ameliore.coton   1050    1261      1500
mil.trad.cereal         450     570       670 
mil.ameliore.cereal     870     1100      1200 
mil.trad.coton          540     680       685  
mil.ameliore.coton      803     1171      1286 
niebe.trad.cereal       830     1300      1420
niebe.ameliore.cereal   1090    1430      1521 

coton.trad.coton        850     1200      1500
coton.ameliore.coton    1242    2436      2959 
mais.trad.coton         2000    2500      3080
mais.ameliore.coton     2450    3000      3400 ;

PARAMETER c(i,j) ;
calcoffre(i,r,k) ..  -SUM(j, Y(i,j,r,k)*X(i,j,r)) +O(i,r,k) =E= 0;  
calccouts(i,r) ..  -SUM(j, c(i,j)*X(i,j,r)) +TC(i,r) =E= 0;  

EQUATION calctransp(i,r,k);
PARAMETER h(i,q,r);
calctransp(i,r,k) .. -SUM(q, h(i,q,r)*T(i,q,r,k)) + TR(i,r,k)=E= 0;

EQUATION equiltrans(i,q,r,k);
equiltrans(i,q,r,k) .. T(i,q,r,k) + T(i,r,q,k) =E= 0;

EQUATION labor(r);
PARAMETERS DMO(i,j), OMO(r);
labor(r) .. SUM(i, SUM(j,DMO(i,j)*X(i,j,r))) =L= OMO(r) ;

EQUATION engrais;
PARAMETER utilisengr(i,j), totengrais;
engrais .. SUM((i,j,r), utilisengr(i,j)*X(i,j,r)) =L= totengrais;

PARAMETER Dequil(i,r), Pequil(i,r);
PARAMETER subsist;
subsist = 180;
SET type /rurale, urbane/;
PARAMETER popcereal(type), popcoton(type), popbamako;
popcereal('rurale') = 4192000;
popcereal('urbane') = 999000;
popcoton('rurale') = 2508000;
popcoton('urbane') = 551000;
popbamako = 941000;

Dequil('sorgho','cereal') = .45*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('sorgho','coton') = .45*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('sorgho','bamako') = .25*subsist*popbamako;
Dequil('mil   ','cereal') = .45*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('mil   ','coton') = .45*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('mil   ','bamako') = .25*subsist*popbamako;
Dequil('niebe','cereal') = 50*(popcereal('rurale')+popcereal('urbane'));
Dequil('niebe','coton') = 50*(popcoton('rurale')+popcoton('urbane'));
Dequil('niebe','bamako') = 50*popbamako;
Dequil('mais','cereal') = .1*subsist*(popcereal('rurale')+popcereal('urbane'));
Dequil('mais','coton') = .1*subsist*(popcoton('rurale')+popcoton('urbane'));
Dequil('mais','bamako') = .1*subsist*popbamako;
Dequil('coton','cereal') = 1;
Dequil('coton','bamako') = 1;
Dequil('coton','coton') = 452046000;

Pequil('sorgho',r) = 99;
Pequil('mil   ',r) = 97;
Pequil('niebe',r) = 171;
Pequil('coton',r) = 155;
Pequil('mais',r) = 83;

PARAMETER epsilon(i,r) ;
epsilon('sorgho',r) = -.5;
epsilon('mil   ',r) = -.5;
epsilon('niebe',r) = -.5;
epsilon('mais',r) = -.5;
epsilon('coton','cereal') = -.1;
epsilon('coton','bamako') = -.1;
epsilon('coton','coton') = -10000000;

A(i,r) = Pequil(i,r)/(Dequil(i,r)*epsilon(i,r)) ;
B(i,r) = Pequil(i,r)*(1 - 1/epsilon(i,r)) ;

H(i,q,r) = 0;
 
S('cereal') = 901906;
S('coton') = 1189789;

TABLE C(i,j)
            trad    ameliore
sorgho      1500     22250
mil         1500     22250 
niebe       1500     23000
coton       32000    52200
mais        51500    55500 ;
 
DMO('sorgho','trad') = 208;
DMO('sorgho','ameliore') = 227;
DMO('mil   ','trad') = 208;
DMO('mil   ','ameliore') = 227;
DMO('niebe','trad') = 379;
DMO('niebe','ameliore') = 440;

OMO('cereal') = (popcereal('rurale')+popcereal('urbane'))*9547/(4+3+4) ;
OMO('coton') = (popcoton('rurale')+popcoton('urbane'))*9547/(4+3+4) ;

utilisengr('sorgho','trad') = 0;  
utilisengr('sorgho','ameliore') = 100;  
utilisengr('mil   ','trad') = 0;  
utilisengr('mil   ','ameliore') = 100;  
utilisengr('niebe','trad') = 100;  
utilisengr('niebe','ameliore') = 100;
utilisengr('coton','trad') = 150;  
utilisengr('coton','ameliore') = 250;
utilisengr('mais','trad') = 150;  
utilisengr('mais','ameliore') = 150;

totengrais = 1500000;

prob('seche') = .3 ;
prob('moyenne') = .45 ;  
prob('bonne')=.25 ;

MODEL modele10 /objectif, terres, equilibre,
             calcoffre, calccouts, calctransp, equiltrans, labor, engrais/ ;
SOLVE modele10 maximizing EBES using NLP;